home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / GROUP1.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-12-13  |  6.6 KB  |  198 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * GROUP 1 (Quick) Commands
  14.  
  15.     xref    _getkey,ask,case,cnt_nl,default,dirty,eol,findpat
  16.     xref    prompt,repflag,reppat,seek,sol
  17.     xdef    group_1,refind,to_end,home
  18.  
  19. #edit.h
  20. #cursor.h
  21. *****************************************************************
  22. * GROUP_1 - group 1 (quick) commands
  23. group_1:
  24.     move.l    #q_cmd,a0    * load up prompt address
  25.     bsr    prompt        * output prompt
  26.     bsr    _getkey        * get switch key
  27.     and.w    #$001F,d0    * make u/l, l/c letters cntrl
  28.     move.l    #table1,a0    * load up case table address
  29.     bra    case        * returns to caller of group_2
  30. q_cmd:    dc.b    'Quick Command: A B C D F K R S',0
  31.     dc.w    0
  32.  
  33. *****************************************************************
  34. * TABLE_1 - switch table for group 1 commands
  35. table1:
  36.     dc.w    8
  37.     dc.w    $01        * ^A find/replace
  38.     dc.l    find_repl
  39.     dc.w    $02        * ^B find block start
  40.     dc.l    find_b_s
  41.     dc.w    $03        * ^C to end of file
  42.     dc.l    to_end
  43.     dc.w    $06        * ^F find
  44.     dc.l    find    
  45.     dc.w    $0B        * ^K find block end
  46.     dc.l    find_b_e
  47.     dc.w    $04        * ^D end of line
  48.     dc.l    eol
  49.     dc.w    $12        * ^R top of file
  50.     dc.l    home
  51.     dc.w    $13        * ^S start of line
  52.     dc.l    sol
  53.     dc.l    default
  54. *****************************************************************
  55. find:
  56.     move.l    #fwhat,a0    * prompt string address
  57.     move.l    #findpat,a1    * find pattern string address
  58.     bsr    ask        * see what human wants
  59.     clr.w    repflag        * zero "replace" flag
  60.     bsr    refind        * go find it
  61.     rts
  62. fwhat:    dc.b    'Find: ',0
  63.     dc.w    0
  64. *****************************************************************
  65. find_repl:
  66.     move.l    #fwhat,a0    * prompt string address
  67.     move.l    #findpat,a1    * find pattern string address
  68.     bsr    ask        * see what human wants
  69.     move.l    #rwhat,a0    * prompt string address
  70.     move.l    #reppat,a1    * replace pattern string address
  71.     bsr    ask        * get reply
  72.     move.w    #-1,repflag    * set "replace" flag
  73.     bsr    refind        * go find it
  74.     rts
  75. rwhat:    dc.b    'Replace: ',0
  76.     dc.w    0
  77. *****************************************************************
  78. refind:
  79.     move.l    e_buf(a5),d0    * calculate bytes past cursor
  80.     sub.l    e_gap(a5),d0    * D0 is bytes + 1
  81.     addq.l    #1,d0        * adjust byte count to actual
  82.     move.l    e_gap(a5),a0    * a0 will be search location
  83.     andi    #$FB,ccr    * reset zero flag
  84.     bra    sk0_ref        * do loop test before looping
  85. lp0_ref:
  86.     move.l    #findpat,a1    * a1 will be search pattern
  87.     addq.l    #1,a0        * bump start pointer
  88.     bsr    instr        * do instring compare
  89. sk0_ref:
  90.     dbeq    d0,lp0_ref    * loop if (d0) AND not zero flag
  91.     bne    sk1_ref        * jump if not found
  92.     move.l    e_gap(a5),a2    * setup to move cursor
  93.     move.l    b_gap(a5),d0    * calculate bytes to move
  94.     sub.l    a2,a0        * a0 holds bytes to move
  95.     add.l    a0,d0        * a1 is desired cursor location 
  96.     bsr    seek        * move cursor
  97.     tst.w    repflag        * see if we're replacing
  98.     beq    sk2_ref        * jump if no.
  99. * replace
  100.     bsr    dirty        * mark file as modified
  101.     move.l    #findpat,a1    * we'll use brute force
  102.     move.l    e_gap(a5),a0    * get end-of-gap
  103. lp1_ref:
  104.     tst.b    (a1)+        * look for end-of-find-pattern
  105.     beq    sk3_ref        * jump out at end of pattern
  106.     addq.l    #1,a0        * pop character out of file
  107.     bra    lp1_ref        * keep it up
  108. sk3_ref:
  109.     move.l    a0,e_gap(a5)    * delete "found" pattern
  110. * insert replacement string
  111. * we really ought to check for room here... 
  112.     move.l    #reppat,a1    * replacement string address
  113.     move.l    b_gap(a5),a0    * destination for string
  114.     move.l    a0,d0        * save cursor position for later
  115. lp2_ref:
  116.     tst.b    (a1)        * see if we have stuff to insert
  117.     beq    sk4_ref        * nope, all done.
  118.     move.b    (a1)+,(a0)+    * transfer a byte
  119.     bra    lp2_ref        * try for next byte
  120. sk4_ref:
  121.     move.l    a0,b_gap(a5)    * reset gap position
  122.     bsr    seek        * fix cursor position
  123.     bra    sk2_ref        * finished.
  124. sk1_ref:
  125.     move.w    #12,ed_err(a5)    * string-not-found error
  126. sk2_ref:
  127.     bsr    cnt_nl        * adjust line counter
  128.     rts
  129. *****************************************************************
  130. * INSTR - tests if a string in contained in the buffer.
  131. instr:
  132.     clr.l    d1        * d1 is compare count
  133. lp0_str:
  134.     tst.b    (a1)        * at end of pattern string?
  135.     beq    sk0_str        * jump if yes (we found it)
  136.     addq.l    #1,d1        * increment compare count
  137.     cmp.b    (a1)+,(a0)+    * check a byte - equal?
  138.     beq    lp0_str        * jump if no - no match
  139. sk0_str:
  140.     sub.l    d1,a0        * reset compare pointer
  141.     sub.l    d1,a1        * reset source pointer
  142.     rts
  143. *****************************************************************
  144. * HOME - moves cursor to top of file
  145. home:
  146.     move.l    b_gap(a5),d0    * get number of bytes to xfer
  147.     sub.l    b_buf(a5),d0    * d0 is number of bytes 
  148.     move.l    b_gap(a5),a0    * a0 is source address
  149.     move.l    e_gap(a5),a1    * a1 is destination address
  150.     bra    sk0_hm        * loop test before 1st transfer
  151. lp0_hm:
  152.     move.b    -(a0),-(a1)    * transfer across cursor gap
  153. sk0_hm:
  154.     dbra    d0,lp0_hm    * loop for all chars 
  155.     move.l    a0,b_gap(a5)    * save ending positions
  156.     move.l    a1,e_gap(a5)
  157.     clr.w    log_lin(a5)    * reset current line counter
  158.     rts    
  159. *****************************************************************
  160. * FIND_B_S - move the cursor to the beginning of the block
  161. find_b_s:
  162.     move.l    blk_st(a5),d0    * load marker
  163.     beq    sk0_fbs        * if zero, there's an error
  164.     bsr    seek        * go find the spot
  165.     bsr    cnt_nl        * reset line count
  166.     rts
  167. sk0_fbs:
  168.     move.w    #4,ed_err(a5)    * mark edit error #4 (block mark)
  169.     rts
  170. *****************************************************************
  171. * FIND_B_E - move the cursor to the end of the block
  172. find_b_e:
  173.     move.l    blk_end(a5),d0    * load marker
  174.     beq    sk0_fbe        * if zero, block's not marked.
  175.     bsr    seek        * go to the spot
  176.     bsr    cnt_nl        * reset line count
  177.     rts
  178. sk0_fbe:
  179.     move.w    #4,ed_err(a5)    * mark edit error #4 (block mark)
  180.     rts
  181. *****************************************************************
  182. * TO_END - moves cursor to end of file
  183. to_end:
  184.     move.l    e_buf(a5),d0    * get number of bytes to xfer
  185.     sub.l    e_gap(a5),d0    * d0 is number of bytes + 1
  186.     move.l    e_gap(a5),a0    * a0 is source address
  187.     move.l    b_gap(a5),a1    * a1 is destination address
  188.     addq.l    #1,d0        * adjust index for cursor update
  189.     bra    sk0_te        * loop test before 1st transfer
  190. lp0_te:
  191.     move.b    (a0)+,(a1)+    * transfer across cursor gap
  192. sk0_te:
  193.     dbra    d0,lp0_te    * loop for all chars 
  194.     move.l    a0,e_gap(a5)    * save ending positions
  195.     move.l    a1,b_gap(a5)
  196.     bsr    cnt_nl        * count lines to cursor
  197.     rts
  198.